1. 로직
Postman / 외부 웹
↓
OData V4 Service Binding
↓
Service Definition
↓
Projection CDS View: ZC_ZEDU_ENROLL
↓
Root CDS View: ZR_ZEDU_ENROLL
↓
Persistent Table: ZEDU_ENROLL
변경 로그 저장
↓
Behavior Pool: ZBP_R_ZEDU_ENROLL
↓
Table: ZEDU_LOG2. 최종 생성 객체
| 구분 | 객체명 | 역할 |
|---|---|---|
| Table | ZEDU_ENROLL |
교육 신청 데이터 저장 |
| Table | ZEDU_LOG |
상태 변경 로그 저장 |
| Root CDS View | ZR_ZEDU_ENROLL |
RAP Transaction Root View |
| Base Behavior | ZR_ZEDU_ENROLL |
Update 가능 여부, Determination 정의 |
| Behavior Pool Class | ZBP_R_ZEDU_ENROLL |
상태 변경 시 로그 저장 로직 구현 |
| Projection CDS View | ZC_ZEDU_ENROLL |
OData/UI에 노출할 Projection View |
| Projection Behavior | ZC_ZEDU_ENROLL |
Projection에서 update 사용 허용 |
| Service Definition | ZUI_ZEDU_ENROLL_TX |
Projection View를 OData 서비스로 expose |
| Service Binding | ZUI_ZEDU_ENROLL_TX_O4 |
OData V4 UI 서비스 publish |
3. ADT에서 파일 생성 순서
ADT 기준으로 아래 순서대로 생성하면 꼬일 가능성이 적다.
1. Database Table 생성
- ZEDU_ENROLL
- ZEDU_LOG
2. Root CDS View 생성
- ZR_ZEDU_ENROLL
3. Base Behavior Definition 생성
- Behavior Definition for ZR_ZEDU_ENROLL
4. Behavior Pool Class 생성
- ZBP_R_ZEDU_ENROLL
5. Projection CDS View 생성
- ZC_ZEDU_ENROLL
6. Projection Behavior Definition 생성
- Behavior Definition for ZC_ZEDU_ENROLL
7. Service Definition 생성
- ZUI_ZEDU_ENROLL_TX
8. Service Binding 생성
- ZUI_ZEDU_ENROLL_TX_O4
- Binding Type: OData V4 - UI
9. Service Binding Activate / Publish
10. Postman으로 CSRF Token 발급 후 PATCH 테스트활성화 순서는 아래처럼 진행한다.
1. ZR_ZEDU_ENROLL CDS
2. ZBP_R_ZEDU_ENROLL Class
3. Behavior Definition ZR_ZEDU_ENROLL
4. ZC_ZEDU_ENROLL CDS
5. Behavior Definition ZC_ZEDU_ENROLL
6. Service Definition ZUI_ZEDU_ENROLL_TX
7. Service Binding ZUI_ZEDU_ENROLL_TX_O4Service Binding 화면에서 Unpublish 버튼만 보이면 이미 Published 상태다.
즉, 별도로 다시 Publish하지 않아도 된다.
4. 네이밍 룰
| Prefix | 의미 | 예시 |
|---|---|---|
ZEDU_ |
프로젝트 업무 객체 | ZEDU_ENROLL, ZEDU_LOG |
ZR_ |
RAP Root View | ZR_ZEDU_ENROLL |
ZI_ |
Interface View / 조회용 기본 CDS | ZI_ZEDU_ENROLL |
ZC_ |
Consumption / Projection View | ZC_ZEDU_ENROLL |
ZUI_ |
UI/OData Service Definition 또는 Binding | ZUI_ZEDU_ENROLL_TX |
ZBP_ |
RAP Behavior Pool Class | ZBP_R_ZEDU_ENROLL |
ZR_를 쓰는 이유
ZR_는 RAP에서 Root Entity 역할을 하는 CDS View에 붙였다.
ZR = Root이 객체는 실제 DB 테이블과 RAP Behavior를 연결하는 중심이다.
ZR_ZEDU_ENROLL
→ persistent table zedu_enroll
→ update 가능
→ behavior pool 연결ZC_를 쓰는 이유
ZC_는 외부 노출용 Projection / Consumption View에 붙였다.
ZC = Consumption외부 OData, Fiori Elements, UI Preview는 보통 Root View를 직접 노출하지 않고 Projection View를 통해 노출한다.
ZR_ZEDU_ENROLL 내부 Transaction Root
↓
ZC_ZEDU_ENROLL 외부 노출용 Projection
↓
OData ServiceZBP_R_를 쓰는 이유
ZBP_R_ZEDU_ENROLL은 ZR_ZEDU_ENROLL의 Behavior Pool Class다.
ZBP = Behavior Pool
R = Root View 기준Behavior Pool에는 Determination, Validation, Action 같은 RAP 비즈니스 로직이 들어간다.
5. 최종 소스
5.1 Root CDS View: ZR_ZEDU_ENROLL
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'ZEDU 교육 신청 RAP Root'
define root view entity ZR_ZEDU_ENROLL
as select from zedu_enroll
{
key enroll_id as EnrollId,
course_id as CourseId,
emp_id as EmpId,
emp_name as EmpName,
dept_name as DeptName,
status as Status,
req_date as ReqDate,
comp_date as CompDate,
created_by as CreatedBy,
created_date as CreatedDate
}5.2 Base Behavior Definition: ZR_ZEDU_ENROLL
strict는 제거했다.
현재 Docker Trial 환경에서는 strict를 쓰면 authorization master 또는 authorization dependent 설정을 요구해서 실습용으로는 제거하는 편이 단순하다.
managed implementation in class zbp_r_zedu_enroll unique;
define behavior for ZR_ZEDU_ENROLL alias Enrollment
persistent table zedu_enroll
lock master
{
update;
determination save_log on modify { update; }
field ( readonly ) EnrollId;
field ( readonly ) CourseId;
field ( readonly ) EmpId;
field ( readonly ) EmpName;
field ( readonly ) DeptName;
field ( readonly ) ReqDate;
field ( readonly ) CreatedBy;
field ( readonly ) CreatedDate;
mapping for zedu_enroll
{
EnrollId = enroll_id;
CourseId = course_id;
EmpId = emp_id;
EmpName = emp_name;
DeptName = dept_name;
Status = status;
ReqDate = req_date;
CompDate = comp_date;
CreatedBy = created_by;
CreatedDate = created_date;
}
}주의했던 부분:
determination save_log on modify { update; }처음에 아래처럼 작성하면 환경에 따라 오류가 발생했다.
determination save_log on save { update; }발생 오류:
The trigger "update" is only allowed in combination with "create" here.그래서 on modify로 변경했다.
5.3 Behavior Pool Class: ZBP_R_ZEDU_ENROLL
Class 탭
CLASS zbp_r_zedu_enroll DEFINITION
PUBLIC
ABSTRACT
FINAL
FOR BEHAVIOR OF zr_zedu_enroll.
ENDCLASS.
CLASS zbp_r_zedu_enroll IMPLEMENTATION.
ENDCLASS.Local Types 탭
CLASS lhc_enrollment DEFINITION INHERITING FROM cl_abap_behavior_handler.
PRIVATE SECTION.
METHODS save_log FOR DETERMINE ON MODIFY
IMPORTING keys FOR Enrollment~save_log.
ENDCLASS.
CLASS lhc_enrollment IMPLEMENTATION.
METHOD save_log.
DATA: ls_log TYPE zedu_log,
lv_log_id TYPE zedu_log-log_id,
lv_prefix TYPE c LENGTH 17,
lv_seq TYPE n LENGTH 3,
lv_msg TYPE zedu_log-msg_text,
lv_old_status TYPE zedu_enroll-status.
READ ENTITIES OF zr_zedu_enroll IN LOCAL MODE
ENTITY Enrollment
FIELDS ( EnrollId CourseId Status )
WITH CORRESPONDING #( keys )
RESULT DATA(lt_enroll).
CONCATENATE 'LOG' sy-datum sy-uzeit INTO lv_prefix.
LOOP AT lt_enroll INTO DATA(ls_enroll).
CLEAR lv_old_status.
SELECT SINGLE status
FROM zedu_enroll
INTO lv_old_status
WHERE enroll_id = ls_enroll-EnrollId.
IF sy-subrc = 0 AND lv_old_status = ls_enroll-Status.
CONTINUE.
ENDIF.
CLEAR: ls_log,
lv_log_id,
lv_seq,
lv_msg.
CONCATENATE '교육 신청 상태 변경:'
lv_old_status
'->'
ls_enroll-Status
INTO lv_msg SEPARATED BY space.
DO 999 TIMES.
lv_seq = sy-index.
CONCATENATE lv_prefix lv_seq INTO lv_log_id.
CLEAR ls_log.
ls_log-mandt = sy-mandt.
ls_log-log_id = lv_log_id.
ls_log-process_type = 'S'.
ls_log-ref_id = ls_enroll-EnrollId.
ls_log-course_id = ls_enroll-CourseId.
ls_log-enroll_id = ls_enroll-EnrollId.
ls_log-msg_type = 'S'.
ls_log-msg_text = lv_msg.
ls_log-program_id = sy-repid.
ls_log-created_by = sy-uname.
ls_log-created_date = sy-datum.
ls_log-created_time = sy-uzeit.
INSERT zedu_log FROM ls_log.
IF sy-subrc = 0.
EXIT.
ENDIF.
ENDDO.
ENDLOOP.
ENDMETHOD.
ENDCLASS.주의사항:
RAP Determination 안에서는 COMMIT WORK를 직접 쓰지 않는다.
저장/커밋은 RAP Framework가 처리한다.5.4 Projection CDS View: ZC_ZEDU_ENROLL
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'ZEDU 교육 신청 수정용'
@Metadata.allowExtensions: true
@UI.headerInfo: {
typeName: '교육신청',
typeNamePlural: '교육신청목록',
title: {
type: #STANDARD,
value: 'EnrollId'
}
}
define root view entity ZC_ZEDU_ENROLL
provider contract transactional_query
as projection on ZR_ZEDU_ENROLL
{
@UI.lineItem: [{ position: 10, label: '신청ID' }]
@UI.selectionField: [{ position: 10 }]
key EnrollId,
@UI.lineItem: [{ position: 20, label: '과정ID' }]
CourseId,
@UI.lineItem: [{ position: 30, label: '사번' }]
EmpId,
@UI.lineItem: [{ position: 40, label: '성명' }]
EmpName,
@UI.lineItem: [{ position: 50, label: '부서' }]
DeptName,
@UI.lineItem: [{ position: 60, label: '상태' }]
@UI.selectionField: [{ position: 20 }]
Status,
@UI.lineItem: [{ position: 70, label: '신청일' }]
ReqDate,
@UI.lineItem: [{ position: 80, label: '이수일' }]
CompDate,
@UI.lineItem: [{ position: 90, label: '생성일' }]
CreatedDate
}5.5 Projection Behavior Definition: ZC_ZEDU_ENROLL
projection;
define behavior for ZC_ZEDU_ENROLL alias Enrollment
{
use update;
}5.6 Service Definition: ZUI_ZEDU_ENROLL_TX
@EndUserText.label: 'ZEDU 교육 신청 수정 서비스'
define service ZUI_ZEDU_ENROLL_TX {
expose ZC_ZEDU_ENROLL as Enrollment;
}5.7 Service Binding: ZUI_ZEDU_ENROLL_TX_O4
ADT에서 생성한다.
Name : ZUI_ZEDU_ENROLL_TX_O4
Description : ZEDU Enrollment Transaction OData V4
Service Definition : ZUI_ZEDU_ENROLL_TX
Binding Type : OData V4 - UI생성 후:
Activate
Publish이미 Published 상태면 Unpublish 버튼만 보인다.
그 상태면 정상이다.
6. Postman 테스트
6.1 CSRF Token 발급
GET https://vhcala4hci:50001/sap/opu/odata4/sap/zui_zedu_enroll_tx_o4/srvd/sap/zui_zedu_enroll_tx/0001/?sap-client=001Headers:
x-csrf-token: Fetch
Accept: application/jsonAuthorization:
Basic Auth
DEVELOPER / ABAPtr2023#006.2 PATCH 요청
PATCH https://vhcala4hci:50001/sap/opu/odata4/sap/zui_zedu_enroll_tx_o4/srvd/sap/zui_zedu_enroll_tx/0001/Enrollment(EnrollId='ENR000000001')?sap-client=001Headers:
Accept: application/json
Content-Type: application/json
x-csrf-token: 받은토큰
If-Match: *Body:
{
"Status": "N"
}성공 시 보통 아래 응답이 나온다.
204 No Content7. 로그 확인
SAP GUI 또는 WebGUI에서 확인한다.
SE16N
→ ZEDU_LOG또는 기존 로그 조회 프로그램으로 확인한다.
SE38
→ ZEDU_LOG_DISPLAY정상 로그 예시:
PROCESS_TYPE = S
REF_ID = ENR000000001
ENROLL_ID = ENR000000001
MSG_TYPE = S
MSG_TEXT = 교육 신청 상태 변경: C -> N같은 Status 값으로 PATCH하면 로그가 남지 않는다.
실제 상태가 변경된 경우에만 로그가 저장되도록 처리했다.
COMMENTS
댓글
GitHub 계정으로 로그인하면 댓글을 남길 수 있습니다.
댓글을 불러오는 중입니다.