CSV 샘플 데이터 생성
→ 업로드 Report 생성
→ CSV 파일 선택
→ ZEDU_COURSE INSERT
→ ADT SQL Console로 조회1. 대상 테이블
업로드 대상 테이블은 교육 과정 마스터 테이블인 ZEDU_COURSE이다.
| 테이블명 | 설명 |
|---|---|
ZEDU_COURSE |
교육 과정 마스터 |
업로드 CSV 컬럼은 아래 기준으로 구성했다.
| CSV 컬럼 | SAP 필드 | 설명 |
|---|---|---|
COURSE_ID |
COURSE_ID |
과정 ID |
COURSE_NAME |
COURSE_NAME |
과정명 |
COURSE_TYPE |
COURSE_TYPE |
과정 유형 |
START_DATE |
START_DATE |
시작일 |
END_DATE |
END_DATE |
종료일 |
CREATED_BY |
CREATED_BY |
생성자 |
CREATED_DATE |
CREATED_DATE |
생성일 |
MANDT는 CSV에 포함하지 않고, ABAP Report에서 sy-mandt 기준으로 처리했다.
2. CSV 샘플 데이터
CSV 파일은 아래 형태로 준비했다.
COURSE_ID,COURSE_NAME,COURSE_TYPE,START_DATE,END_DATE,CREATED_BY,CREATED_DATE
ABAP_CDS,ABAP CDS View 기초,SAP,20260901,20260905,DEVELOPER,20260813
ABAP_RAP,ABAP RAP 서비스 개발,SAP,20260908,20260912,DEVELOPER,20260813
ODATA_BASIC,OData 서비스 기초,SAP,20260915,20260919,DEVELOPER,20260813
FIORI_BASIC,Fiori Elements 기초,SAP,20260922,20260926,DEVELOPER,20260813
RFC_BASIC,SAP RFC 연동 기초,SAP,20260929,20261002,DEVELOPER,20260813날짜는 SAP DATS 형식에 맞춰 YYYYMMDD 형태로 작성했다.
Excel 작성
→ CSV UTF-8 형식으로 저장
→ SAP 업로드 Report에서 파일 선택3. 업로드 Report 생성
T-CODE는 SE38 또는 SA38을 사용했다.
SE38
→ Program: ZEDU_UPLOAD_COURSE_CSV
→ Create
→ Type: Executable Program
→ Source Code 작성
→ Activate업로드 Report는 로컬 PC의 CSV 파일을 읽은 뒤 ZEDU_COURSE 테이블에 INSERT하는 방식이다.
REPORT zedu_upload_course_csv.
TYPES: BEGIN OF ty_csv,
course_id TYPE zedu_course-course_id,
course_name TYPE zedu_course-course_name,
course_type TYPE zedu_course-course_type,
start_date TYPE zedu_course-start_date,
end_date TYPE zedu_course-end_date,
created_by TYPE zedu_course-created_by,
created_date TYPE zedu_course-created_date,
END OF ty_csv.
DATA: gt_csv TYPE STANDARD TABLE OF ty_csv,
gs_csv TYPE ty_csv,
gt_course TYPE STANDARD TABLE OF zedu_course,
gs_course TYPE zedu_course.
DATA: gt_file TYPE STANDARD TABLE OF string,
gv_file TYPE string.
PARAMETERS p_file TYPE string LOWER CASE.
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
DATA: lt_filetable TYPE filetable,
lv_rc TYPE i.
cl_gui_frontend_services=>file_open_dialog(
CHANGING
file_table = lt_filetable
rc = lv_rc
).
IF lv_rc > 0.
READ TABLE lt_filetable INTO DATA(ls_file) INDEX 1.
IF sy-subrc = 0.
p_file = ls_file-filename.
ENDIF.
ENDIF.
START-OF-SELECTION.
PERFORM upload_csv.
PERFORM convert_data.
PERFORM insert_data.
FORM upload_csv.
gv_file = p_file.
cl_gui_frontend_services=>gui_upload(
EXPORTING
filename = gv_file
filetype = 'ASC'
has_field_separator = abap_false
CHANGING
data_tab = gt_file
).
ENDFORM.
FORM convert_data.
DATA lv_line TYPE string.
LOOP AT gt_file INTO lv_line.
IF sy-tabix = 1.
CONTINUE.
ENDIF.
CLEAR gs_csv.
SPLIT lv_line AT ','
INTO gs_csv-course_id
gs_csv-course_name
gs_csv-course_type
gs_csv-start_date
gs_csv-end_date
gs_csv-created_by
gs_csv-created_date.
IF gs_csv-course_id IS INITIAL.
CONTINUE.
ENDIF.
APPEND gs_csv TO gt_csv.
ENDLOOP.
ENDFORM.
FORM insert_data.
CLEAR gt_course.
LOOP AT gt_csv INTO gs_csv.
CLEAR gs_course.
gs_course-mandt = sy-mandt.
gs_course-course_id = gs_csv-course_id.
gs_course-course_name = gs_csv-course_name.
gs_course-course_type = gs_csv-course_type.
gs_course-start_date = gs_csv-start_date.
gs_course-end_date = gs_csv-end_date.
gs_course-created_by = gs_csv-created_by.
gs_course-created_date = gs_csv-created_date.
APPEND gs_course TO gt_course.
ENDLOOP.
IF gt_course IS INITIAL.
MESSAGE '업로드할 데이터가 없습니다.' TYPE 'S' DISPLAY LIKE 'E'.
RETURN.
ENDIF.
INSERT zedu_course FROM TABLE gt_course ACCEPTING DUPLICATE KEYS.
COMMIT WORK AND WAIT.
WRITE: / 'CSV Read Count :', lines( gt_csv ).
WRITE: / 'Insert Try Count :', lines( gt_course ).
WRITE: / 'Inserted Count :', sy-dbcnt.
WRITE: / 'Upload Completed.'.
ENDFORM.4. CSV 업로드 실행
Report 생성 후 SA38에서 실행했다.
SA38
→ ZEDU_UPLOAD_COURSE_CSV 입력
→ Execute
→ p_file에서 CSV 파일 선택
→ Execute실행 후 화면에서 읽은 건수와 INSERT 건수를 확인한다.
CSV Read Count
Insert Try Count
Inserted Count
Upload Completed5. ADT SQL Console 조회
업로드 결과는 ADT SQL Console에서 확인했다.
ADT
→ ABAP Project 우클릭
→ Open ABAP SQL Console
→ SELECT 문 실행전체 조회
SELECT FROM zedu_course
FIELDS course_id,
course_name,
course_type,
start_date,
end_date,
created_by,
created_date
ORDER BY course_id.과정 유형별 조회
SELECT FROM zedu_course
FIELDS course_id,
course_name,
course_type,
start_date,
end_date
WHERE course_type = 'SAP'
ORDER BY start_date DESCENDING,
course_id.과정명 조건 조회
SELECT FROM zedu_course
FIELDS course_id,
course_name,
start_date,
end_date
WHERE course_name LIKE '%ABAP%'
ORDER BY start_date DESCENDING.
COMMENTS
댓글
GitHub 계정으로 로그인하면 댓글을 남길 수 있습니다.
댓글을 불러오는 중입니다.